# Copyright 1999-2008 Gentoo Foundation
# Distributed under the terms of the GNU General Public License v2

inherit apache-module subversion

DESCRIPTION="Apache 2 module that provides flexible templating from an SQL database"
HOMEPAGE="http://www.dmi.me.uk/code/apache/mod_sqltemplate/"
SRC_URI=""

LICENSE="BSD"
SLOT="0"
KEYWORDS="~amd64 ~x86"
IUSE="debug"

DEPEND=""
RDEPEND=""

APACHE2_MOD_CONF="99_${PN}"
APACHE2_MOD_DEFINE="SQLTEMPLATE"

ESVN_REPO_URI="http://svn.dmi.me.uk/mod_sqltemplate/trunk"

need_apache2_2

pkg_setup() {
	if use 'debug' ; then
		elog
		elog "Note that you can select a debug level from 1 to 4 by setting the"
		elog "SQLTPL_DEBUGLVL environment variable. The default debug level is 1,"
		elog "and the currently-selected level is ${SQLTPL_DEBUGLVL:-1}."
		elog "The higher the debug level, the more verbose the output."
		elog
	fi
}

src_compile() {
	: ${SQLTPL_DEBUGLVL:=1}
	APXS2_ARGS="-c ${PN}.c"
	use 'debug' && APXS2_ARGS="-D_DEBUG_SQLTPL=${SQLTPL_DEBUGLVL} ${APXS2_ARGS}"

	apache-module_src_compile
}

pkg_postinst() {
	apache-module_pkg_postinst
	elog
	elog "Make sure you edit the configuration file, as it is only an example of"
	elog "how to use this module's syntax."
	elog
	if use debug ; then
		ewarn "Note that the debugging output can be quite verbose, and will be"
		ewarn "output to standard error when Apache starts."
		ewarn
		ewarn "The debug output may contain passwords!"
		ewarn
	fi
}